#!/usr/bin/env perl

# Copyright (C) 2005-2007  Joshua Hoblitt
#
# $Id: neb-initdb,v 1.8 2008-06-30 22:44:12 jhoblitt Exp $

use strict;
use warnings FATAL => qw( all );

use vars qw( $VERSION );
$VERSION = '0.03';

use DBI;
use Nebulous::Server::SQL;

use Getopt::Long qw( GetOptions :config auto_help auto_version );
use Pod::Usage qw( pod2usage );

my ($db, $dbhost, $dbuser, $dbpass);

$db     = $ENV{'NEB_DB'} unless $db;
$dbhost = $ENV{'NEB_DBHOST'} || 'localhost';
$dbuser = $ENV{'NEB_USER'} unless $dbuser;
$dbpass = $ENV{'NEB_PASS'} unless $dbpass;

GetOptions(
    'db=s'      => \$db,
    'host=s'    => \$dbhost,
    'user=s'    => \$dbuser,
    'pass=s'    => \$dbpass,
) || pod2usage( 2 );

pod2usage( -msg => "Unknown option: @ARGV", -exitval => 2 ) if @ARGV;
pod2usage( -msg => "Required options: --db --user --pass", -exitval => 2 )
    unless $db && $dbuser && $dbpass;

my $dbh = DBI->connect(
    "DBI:mysql:database=$db:host=$dbhost",
    $dbuser,
    $dbpass,
    {
        RaiseError => 1,
        PrintError => 0,
        AutoCommit => 1,
    },
);

my $sql = Nebulous::Server::SQL->new();

print "Dropping any existing tables...";

foreach my $statement (@{ $sql->get_db_clear }) {
    $dbh->do( $statement );
}

print " OK\nCreating new tables...";

foreach my $statement (@{ $sql->get_db_schema }) {
    $dbh->do( $statement );
}

print " OK\n";

__END__

=pod

=head1 NAME

neb-initdb - initialize a Nebulous server database

=head1 SYNOPSIS

    neb-initdb [--db <database>] [--user <username>] [--pass <password>]

=head1 DESCRIPTION

This program initialize a database for use by L<Nebulous::Server> by creating
the appropriate set of tables.  Any pre-existing tables with conflicting names
are first removed.

=head1 OPTIONS

=over 4

=item * --db|-d <database>

Name of database (C<namespace>) to create tables in.

Optional if the appropriate environment variable is set.

=item * --user|-u <username>

Username to authenticate with.

Optional if the appropriate environment variable is set.

=item * --pass|-p <password>

Password to authenticate with.

Optional if the appropriate environment variable is set.

=back

=head1 ENVIRONMENT

These environment variables may be used in place of the specified command line
options.  All command line option will override the corresponding environment
value.

=over 4

=item * C<NEB_DB>

Equivalent to --db|-d

=item * C<NEB_USER>

Equivalent to --user|-u

=item * C<NEB_PASS>

Equivalent to --pass|-p 

=back

=head1 CREDITS

Just me, myself, and I.

=head1 SUPPORT

Please contact the author directly via e-mail.

=head1 AUTHOR

Joshua Hoblitt <jhoblitt@cpan.org>

=head1 COPYRIGHT

Copyright (C) 2005-2007  Joshua Hoblitt.  All rights reserved.

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT ANY
WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
PARTICULAR PURPOSE.  See the GNU General Public License for more details.

You should have received a copy of the GNU General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA  02111-1307, USA.

The full text of the license can be found in the L<perlgpl> Pod as supplied
with Perl 5.8.1 and later.

=head1 SEE ALSO

L<Nebulous::Server>, L<neb-addvol>, L<neb-df>, L<nebdiskd>

=cut
