#!/usr/bin/env perl

# Copyright (C) 2005  Joshua Hoblitt
#
# $Id: mdb-add-new-from-psftp,v 1.2 2005-10-14 23:28:06 jhoblitt Exp $

use strict;
use warnings FATAL => qw( all );

use vars qw( $VERSION );
$VERSION = '0.01';

use PS::IPP::MetaDB;
use PS::IPP::PSFTP;

use Getopt::Long qw( GetOptions :config auto_help auto_version gnu_getopt );
use Pod::Usage qw( pod2usage );

my ($base_url, $recipient);
my ($dsn, $dbuser, $dbpass);

GetOptions(
    'dsn=s'         => \$dsn,
    'user=s'        => \$dbuser,
    'pass=s'        => \$dbpass,
    'base_url=s'    => \$base_url,
    'recipient=s'   => \$recipient,
) || pod2usage( 2 );

$dsn    = $ENV{'MDB_DSN'} unless $dsn;
$dbuser = $ENV{'MDB_USER'} unless $dbuser;
$dbpass = $ENV{'MDB_PASS'} unless $dbpass;

pod2usage( -msg => "Unknown option: @ARGV", -exitval => 2 ) if @ARGV;
pod2usage( -msg => "Required options: --dsn --user", -exitval => 3 )
    unless defined $dsn and defined $dbuser;
pod2usage(
    -msg => "Required options: --base_url --recipient",
    -exitval => 4,
) unless defined $base_url and defined $recipient;

my $psftp = PS::IPP::PSFTP->new(
    base_url    => $base_url,
    recipient   => $recipient,
);

# do some sort of error checking
my $filelist = $psftp->files_available;

PS::IPP::MetaDB->init(
    dsn     => $dsn,
    user    => $dbuser,
    passwd  => $dbpass,
);

foreach my $file (@$filelist) {
    next unless $file->type eq 'expsoure';

    PS::IPP::MetaDB->add_new(
        exp_id      => $file->attributes->{exp_id},
        class       => $file->attributes->{class},
        class_id    => $file->attributes->{class_id},
        camera      => $file->attributes->{camera},
        stamp       => $file->stamp,
        file_id     => $file->file_id,
        size        => $file->size,
        md5         => $file->md5,
        url         => $file->url,
    );
}

__END__

=pod

=head1 NAME

mdb-add-new - register a new file as available for download

=head1 SYNOPSIS

    mdb-add-new [--db <database>] [--user <username>] [--pass <password>]

=head1 DESCRIPTION

=head1 OPTIONS

=over 4

=item * --db|-d <database>

Name of database (C<namespace>) to create tables in.

Optional if the appropriate environment variable is set.

=item * --user|-u <username>

Username to authenticate with.

Optional if the appropriate environment variable is set.

=item * --pass|-p <password>

Password to authenticate with.

Optional if the appropriate environment variable is set.

=back

=head1 ENVIRONMENT

These environment variables may be used in place of the specified command line
options.  All command line option will override the corresponding environment
value.

=over 4

=item * C<MDB_DB>

Equivalent to --db|-d

=item * C<MDB_USER>

Equivalent to --user|-u

=item * C<MDB_PASS>

Equivalent to --pass|-p

=back

=head1 CREDITS

Just me, myself, and I.

=head1 SUPPORT

Please contact the author directly via e-mail.

=head1 AUTHOR

Joshua Hoblitt <jhoblitt@cpan.org>

=head1 COPYRIGHT

Copyright (C) 2005  Joshua Hoblitt.  All rights reserved.

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT ANY
WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
PARTICULAR PURPOSE.  See the GNU General Public License for more details.

You should have received a copy of the GNU General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA  02111-1307, USA.

The full text of the license can be found in the L<perlgpl> Pod as supplied
with Perl 5.8.1 and later.

=head1 SEE ALSO

L<PS::IPP::MetaDB>

=cut
